diff --git a/airootfs/etc/skel/.config/fish/auto-Hypr.fish b/airootfs/etc/skel/.config/fish/auto-Hypr.fish
new file mode 100644
index 0000000..893451c
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/auto-Hypr.fish
@@ -0,0 +1,5 @@
+# Auto start Hyprland on tty1
+if test -z "$DISPLAY" ;and test "$XDG_VTNR" -eq 1
+    mkdir -p ~/.cache
+    exec start-hyprland > ~/.cache/hyprland.log 2>&1
+end
diff --git a/airootfs/etc/skel/.config/fish/completions/fisher.fish b/airootfs/etc/skel/.config/fish/completions/fisher.fish
new file mode 100644
index 0000000..6d23ce4
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/completions/fisher.fish
@@ -0,0 +1,7 @@
+complete --command fisher --exclusive --long help --description "Print help"
+complete --command fisher --exclusive --long version --description "Print version"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments install --description "Install plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments update --description "Update installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments remove --description "Remove installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments list --description "List installed plugins matching regex"
+complete --command fisher --exclusive --condition "__fish_seen_subcommand_from update remove" --arguments "(fisher list)"
diff --git a/airootfs/etc/skel/.config/fish/completions/nvm.fish b/airootfs/etc/skel/.config/fish/completions/nvm.fish
new file mode 100644
index 0000000..14be1b7
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/completions/nvm.fish
@@ -0,0 +1,21 @@
+complete --command nvm --exclusive
+complete --command nvm --exclusive --long version --description "Print version"
+complete --command nvm --exclusive --long help --description "Print help"
+complete --command nvm --long silent --description "Suppress standard output"
+
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments install --description "Download and activate the specified Node version"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments use --description "Activate the specified Node version in the current shell"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments list --description "List installed Node versions"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments list-remote --description "List available Node versions to install"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments current --description "Print the currently-active Node version"
+complete --command nvm --exclusive --condition "__fish_seen_subcommand_from install" --arguments "(
+    test -e $nvm_data && string split ' ' <$nvm_data/.index
+)"
+complete --command nvm --exclusive --condition "__fish_seen_subcommand_from use" --arguments "(_nvm_list | string split ' ')"
+complete --command nvm --exclusive --condition __fish_use_subcommand --arguments uninstall --description "Uninstall the specified Node version"
+complete --command nvm --exclusive --condition "__fish_seen_subcommand_from uninstall" --arguments "(
+    _nvm_list | string split ' ' | string replace system ''
+)"
+complete --command nvm --exclusive --condition "__fish_seen_subcommand_from use uninstall" --arguments "(
+    set --query nvm_default_version && echo default
+)"
diff --git a/airootfs/etc/skel/.config/fish/conf.d/fish_frozen_key_bindings.fish b/airootfs/etc/skel/.config/fish/conf.d/fish_frozen_key_bindings.fish
new file mode 100644
index 0000000..495aee9
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/conf.d/fish_frozen_key_bindings.fish
@@ -0,0 +1,14 @@
+# This file was created by fish when upgrading to version 4.3, to migrate
+# the 'fish_key_bindings' variable from its old default scope (universal)
+# to its new default scope (global).  We recommend you delete this file
+# and configure key bindings in ~/.config/fish/config.fish if needed.
+
+# set --global fish_key_bindings fish_default_key_bindings
+
+# Prior to version 4.3, fish shipped an event handler that runs
+# `set --universal fish_key_bindings fish_default_key_bindings`
+# whenever the fish_key_bindings variable is erased.
+# This means that as long as any fish < 4.3 is still running on this system,
+# we cannot complete the migration.
+# As a workaround, erase the universal variable at every shell startup.
+set --erase --universal fish_key_bindings
diff --git a/airootfs/etc/skel/.config/fish/conf.d/fish_frozen_theme.fish b/airootfs/etc/skel/.config/fish/conf.d/fish_frozen_theme.fish
new file mode 100644
index 0000000..bf656ee
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/conf.d/fish_frozen_theme.fish
@@ -0,0 +1,37 @@
+# This file was created by fish when upgrading to version 4.3, to migrate
+# theme variables from universal to global scope.
+# Don't edit this file, as it will be written by the web-config tool (`fish_config`).
+# To customize your theme, delete this file and see
+#     help interactive#syntax-highlighting
+# or
+#     man fish-interactive | less +/^SYNTAX.HIGHLIGHTING
+# for appropriate commands to add to ~/.config/fish/config.fish instead.
+# See also the release notes for fish 4.3.0 (run `help relnotes`).
+
+set --global fish_color_autosuggestion 555 brblack
+set --global fish_color_cancel -r
+set --global fish_color_command blue
+set --global fish_color_comment red
+set --global fish_color_cwd green
+set --global fish_color_cwd_root red
+set --global fish_color_end green
+set --global fish_color_error brred
+set --global fish_color_escape brcyan
+set --global fish_color_history_current --bold
+set --global fish_color_host normal
+set --global fish_color_host_remote yellow
+set --global fish_color_normal normal
+set --global fish_color_operator brcyan
+set --global fish_color_param cyan
+set --global fish_color_quote yellow
+set --global fish_color_redirection cyan --bold
+set --global fish_color_search_match --background=111
+set --global fish_color_selection white --bold --background=brblack
+set --global fish_color_status red
+set --global fish_color_user brgreen
+set --global fish_color_valid_path --underline
+set --global fish_pager_color_completion normal
+set --global fish_pager_color_description B3A06D yellow -i
+set --global fish_pager_color_prefix cyan --bold --underline
+set --global fish_pager_color_progress brwhite --background=cyan
+set --global fish_pager_color_selected_background -r
diff --git a/airootfs/etc/skel/.config/fish/conf.d/nvm.fish b/airootfs/etc/skel/.config/fish/conf.d/nvm.fish
new file mode 100644
index 0000000..7545699
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/conf.d/nvm.fish
@@ -0,0 +1,28 @@
+set --query XDG_DATA_HOME || set --local XDG_DATA_HOME ~/.local/share
+set --query nvm_mirror || set --global nvm_mirror https://nodejs.org/dist
+set --query nvm_data || set --global nvm_data $XDG_DATA_HOME/nvm
+
+function _nvm_install --on-event nvm_install
+    test ! -d $nvm_data && command mkdir -p $nvm_data
+    echo "Downloading the Node distribution index..." 2>/dev/null
+    _nvm_index_update
+end
+
+function _nvm_update --on-event nvm_update
+    set --query --universal nvm_data && set --erase --universal nvm_data
+    set --query --universal nvm_mirror && set --erase --universal nvm_mirror
+    set --query nvm_mirror || set --global nvm_mirror https://nodejs.org/dist
+end
+
+function _nvm_uninstall --on-event nvm_uninstall
+    command rm -rf $nvm_data
+
+    set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
+
+    set --names | string replace --filter --regex -- "^nvm" "set --erase nvm" | source
+    functions --erase (functions --all | string match --entire --regex -- "^_nvm_")
+end
+
+if status is-interactive && set --query nvm_default_version && ! set --query nvm_current_version
+    nvm use --silent $nvm_default_version
+end
diff --git a/airootfs/etc/skel/.config/fish/config.fish b/airootfs/etc/skel/.config/fish/config.fish
new file mode 100644
index 0000000..f10482d
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/config.fish
@@ -0,0 +1,33 @@
+# Commands to run in interactive sessions can go here
+if status is-interactive
+    # No greeting
+    set fish_greeting
+
+    # Use starship
+    function starship_transient_prompt_func
+        starship module character
+    end
+    if test "$TERM" != "linux"
+        starship init fish | source
+        enable_transience
+    end
+    
+    # Colors
+    if test -f ~/.local/state/quickshell/user/generated/terminal/sequences.txt
+        cat ~/.local/state/quickshell/user/generated/terminal/sequences.txt
+    end
+
+    # Aliases
+    # kitty doesn't clear properly so we need to do this weird printing
+    alias clear "printf '\033[2J\033[3J\033[1;1H'"
+    alias celar "printf '\033[2J\033[3J\033[1;1H'"
+    alias claer "printf '\033[2J\033[3J\033[1;1H'"
+    alias pamcan pacman
+    alias q 'qs -c ii'
+    if test "$TERM" != "linux"
+        alias ls 'eza --icons'
+    end
+    if test "$TERM" = "xterm-kitty"
+        alias ssh 'kitten ssh'
+    end
+end
diff --git a/airootfs/etc/skel/.config/fish/fish_plugins b/airootfs/etc/skel/.config/fish/fish_plugins
new file mode 100644
index 0000000..9673b42
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/fish_plugins
@@ -0,0 +1,2 @@
+jorgebucaran/fisher
+jorgebucaran/nvm.fish
diff --git a/airootfs/etc/skel/.config/fish/fish_variables b/airootfs/etc/skel/.config/fish/fish_variables
new file mode 100644
index 0000000..c615491
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/fish_variables
@@ -0,0 +1,7 @@
+# This file contains fish universal variable definitions.
+# VERSION: 3.0
+SETUVAR __fish_initialized:4300
+SETUVAR _fisher_jorgebucaran_2F_fisher_files:\x7e/\x2econfig/fish/functions/fisher\x2efish\x1e\x7e/\x2econfig/fish/completions/fisher\x2efish
+SETUVAR _fisher_jorgebucaran_2F_nvm_2E_fish_files:\x7e/\x2econfig/fish/functions/_nvm_index_update\x2efish\x1e\x7e/\x2econfig/fish/functions/_nvm_list\x2efish\x1e\x7e/\x2econfig/fish/functions/_nvm_version_activate\x2efish\x1e\x7e/\x2econfig/fish/functions/_nvm_version_deactivate\x2efish\x1e\x7e/\x2econfig/fish/functions/nvm\x2efish\x1e\x7e/\x2econfig/fish/conf\x2ed/nvm\x2efish\x1e\x7e/\x2econfig/fish/completions/nvm\x2efish
+SETUVAR _fisher_plugins:jorgebucaran/fisher\x1ejorgebucaran/nvm\x2efish
+SETUVAR _fisher_upgraded_to_4_4:\x1d
diff --git a/airootfs/etc/skel/.config/fish/functions/_nvm_index_update.fish b/airootfs/etc/skel/.config/fish/functions/_nvm_index_update.fish
new file mode 100644
index 0000000..c66753d
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/_nvm_index_update.fish
@@ -0,0 +1,20 @@
+function _nvm_index_update
+    test ! -d $nvm_data && command mkdir -p $nvm_data
+
+    set --local index $nvm_data/.index
+
+    if not command curl -q --location --silent $nvm_mirror/index.tab >$index.temp
+        command rm -f $index.temp
+        echo "nvm: Can't update index, host unavailable: \"$nvm_mirror\"" >&2
+        return 1
+    end
+
+    command awk -v OFS=\t '
+        /v0.9.12/ { exit } # Unsupported
+        NR > 1 {
+            print $1 (NR == 2  ? " latest" : $10 != "-" ? " lts/" tolower($10) : "")
+        }
+    ' $index.temp >$index
+
+    command rm -f $index.temp
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/_nvm_list.fish b/airootfs/etc/skel/.config/fish/functions/_nvm_list.fish
new file mode 100644
index 0000000..1623bb8
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/_nvm_list.fish
@@ -0,0 +1,14 @@
+function _nvm_list
+    set --local versions $nvm_data/*
+
+    set --query versions[1] &&
+        string match --entire --regex -- (
+            string replace --all -- $nvm_data/ "" $versions |
+            string match --regex -- "v\d.+" |
+            string escape --style=regex |
+            string join "|"
+        ) <$nvm_data/.index
+
+    command --all node |
+        string match --quiet --invert --regex -- "^$nvm_data" && echo system
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/_nvm_version_activate.fish b/airootfs/etc/skel/.config/fish/functions/_nvm_version_activate.fish
new file mode 100644
index 0000000..f7dfef7
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/_nvm_version_activate.fish
@@ -0,0 +1,4 @@
+function _nvm_version_activate --argument-names ver
+    set --global --export nvm_current_version $ver
+    set --prepend PATH $nvm_data/$ver/bin
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/_nvm_version_deactivate.fish b/airootfs/etc/skel/.config/fish/functions/_nvm_version_deactivate.fish
new file mode 100644
index 0000000..24dd36e
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/_nvm_version_deactivate.fish
@@ -0,0 +1,5 @@
+function _nvm_version_deactivate --argument-names ver
+    test "$nvm_current_version" = "$ver" && set --erase nvm_current_version
+    set --local index (contains --index -- $nvm_data/$ver/bin $PATH) &&
+        set --erase PATH[$index]
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/edit.fish b/airootfs/etc/skel/.config/fish/functions/edit.fish
new file mode 100644
index 0000000..4ca2471
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/edit.fish
@@ -0,0 +1,3 @@
+function edit --wraps=nvim --description 'alias edit=nvim'
+    nvim $argv
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/fisher.fish b/airootfs/etc/skel/.config/fish/functions/fisher.fish
new file mode 100644
index 0000000..4f5be4f
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/fisher.fish
@@ -0,0 +1,251 @@
+function fisher --argument-names cmd --description "A plugin manager for Fish"
+    set --query fisher_path || set --local fisher_path $__fish_config_dir
+    set --local fisher_version 4.4.8
+    set --local fish_plugins $__fish_config_dir/fish_plugins
+
+    switch "$cmd"
+        case -v --version
+            echo "fisher, version $fisher_version"
+        case "" -h --help
+            echo "Usage: fisher install   <plugins...>  Install plugins"
+            echo "       fisher remove    <plugins...>  Remove installed plugins" 
+            echo "       fisher uninstall <plugins...>  Remove installed plugins (alias)" 
+            echo "       fisher update    <plugins...>  Update installed plugins"
+            echo "       fisher update                  Update all installed plugins"
+            echo "       fisher list    [<regex>]       List installed plugins matching regex"
+            echo "Options:"
+            echo "       -v, --version  Print version"
+            echo "       -h, --help     Print this help message"
+            echo "Variables:"
+            echo "       \$fisher_path  Plugin installation path. Default: $__fish_config_dir" | string replace --regex -- $HOME \~
+        case ls list
+            string match --entire --regex -- "$argv[2]" $_fisher_plugins
+        case install update remove uninstall
+            isatty || read --local --null --array stdin && set --append argv $stdin
+
+            test "$cmd" = uninstall && set cmd remove
+
+            set --local install_plugins
+            set --local update_plugins
+            set --local remove_plugins
+            set --local arg_plugins $argv[2..-1]
+            set --local old_plugins $_fisher_plugins
+            set --local new_plugins
+
+            test -e $fish_plugins && set --local file_plugins (string match --regex -- '^[^\s]+$' <$fish_plugins | string replace -- \~ ~)
+
+            if ! set --query argv[2]
+                if test "$cmd" != update
+                    echo "fisher: Not enough arguments for command: \"$cmd\"" >&2 && return 1
+                else if ! set --query file_plugins
+                    echo "fisher: \"$fish_plugins\" file not found: \"$cmd\"" >&2 && return 1
+                end
+                set arg_plugins $file_plugins
+            else if test "$cmd" = install && ! set --query old_plugins[1] 
+                set --append arg_plugins $file_plugins
+            end
+
+            for plugin in $arg_plugins
+                set plugin (test -e "$plugin" && realpath $plugin || string lower -- $plugin)
+                contains -- "$plugin" $new_plugins || set --append new_plugins $plugin
+            end
+
+            if set --query argv[2]
+                for plugin in $new_plugins
+                    if contains -- "$plugin" $old_plugins
+                        test "$cmd" = remove &&
+                            set --append remove_plugins $plugin ||
+                            set --append update_plugins $plugin
+                    else if test "$cmd" = install
+                        set --append install_plugins $plugin
+                    else
+                        echo "fisher: Plugin not installed: \"$plugin\"" >&2 && return 1
+                    end
+                end
+            else
+                for plugin in $new_plugins
+                    contains -- "$plugin" $old_plugins &&
+                        set --append update_plugins $plugin ||
+                        set --append install_plugins $plugin
+                end
+
+                for plugin in $old_plugins
+                    contains -- "$plugin" $new_plugins || set --append remove_plugins $plugin
+                end
+            end
+
+            set --local pid_list
+            set --local source_plugins
+            set --local fetch_plugins $update_plugins $install_plugins
+            set --local fish_path (status fish-path)
+
+            echo (set_color --bold)fisher $cmd version $fisher_version(set_color normal)
+
+            for plugin in $fetch_plugins
+                set --local source (command mktemp -d)
+                set --append source_plugins $source
+
+                command mkdir -p $source/{completions,conf.d,themes,functions}
+
+                $fish_path --command "
+                    if test -e $plugin
+                        command cp -Rf $plugin/* $source
+                    else
+                        set resp (command mktemp)
+                        set temp (command mktemp -d)
+                        set repo (string split -- \@ $plugin) || set repo[2] HEAD
+
+                        if set path (string replace --regex -- '^(https://)?gitlab.com/' '' \$repo[1])
+                            set name (string split -- / \$path)[-1]
+                            set url https://gitlab.com/\$path/-/archive/\$repo[2]/\$name-\$repo[2].tar.gz
+                        else
+                            set url https://api.github.com/repos/\$repo[1]/tarball/\$repo[2]
+                        end
+
+                        echo Fetching (set_color --underline)\$url(set_color normal)
+
+                        set http (command curl -q --silent -L -o \$resp -w %{http_code} \$url)
+
+                        if test \"\$http\" = 200 && command tar -xzC \$temp -f \$resp 2>/dev/null
+                            command cp -Rf \$temp/*/* $source
+                        else if test \"\$http\" = 403
+                            echo fisher: GitHub API rate limit exceeded \(HTTP 403\) >&2
+                            command rm -rf $source
+                        else
+                            echo fisher: Invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
+                            command rm -rf $source
+                        end
+
+                        command rm -rf \$temp
+                    end
+
+                    set files $source/* && string match --quiet --regex -- .+\.fish\\\$ \$files
+                " &
+
+                set --append pid_list (jobs --last --pid)
+            end
+
+            wait $pid_list 2>/dev/null
+
+            for plugin in $fetch_plugins
+                if set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
+                    if set --local index (contains --index -- "$plugin" $install_plugins)
+                        set --erase install_plugins[$index]
+                    else
+                        set --erase update_plugins[(contains --index -- "$plugin" $update_plugins)]
+                    end
+                end
+            end
+
+            for plugin in $update_plugins $remove_plugins
+                if set --local index (contains --index -- "$plugin" $_fisher_plugins)
+                    set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                    if contains -- "$plugin" $remove_plugins
+                        for name in (string replace --filter --regex -- '.+/conf\.d/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                            emit {$name}_uninstall
+                        end
+                        printf "%s\n" Removing\ (set_color red --bold)$plugin(set_color normal) "         "$$plugin_files_var | string replace -- \~ ~
+                        set --erase _fisher_plugins[$index]
+                    end
+
+                    command rm -rf (string replace -- \~ ~ $$plugin_files_var)
+
+                    functions --erase (string replace --filter --regex -- '.+/functions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+
+                    for name in (string replace --filter --regex -- '.+/completions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                        complete --erase --command $name
+                    end
+
+                    set --erase $plugin_files_var
+                end
+            end
+
+            if set --query update_plugins[1] || set --query install_plugins[1]
+                command mkdir -p $fisher_path/{functions,themes,conf.d,completions}
+            end
+
+            for plugin in $update_plugins $install_plugins
+                set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
+                set --local files $source/{functions,themes,conf.d,completions}/*
+
+                if set --local index (contains --index -- $plugin $install_plugins)
+                    set --local user_files $fisher_path/{functions,themes,conf.d,completions}/*
+                    set --local conflict_files
+
+                    for file in (string replace -- $source/ $fisher_path/ $files)
+                        contains -- $file $user_files && set --append conflict_files $file
+                    end
+
+                    if set --query conflict_files[1] && set --erase install_plugins[$index]
+                        echo -s "fisher: Cannot install \"$plugin\": please remove or move conflicting files first:" \n"        "$conflict_files >&2
+                        continue
+                    end
+                end
+
+                for file in (string replace -- $source/ "" $files)
+                    command cp -RLf $source/$file $fisher_path/$file
+                end
+
+                set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                set --query files[1] && set --universal $plugin_files_var (string replace -- $source $fisher_path $files | string replace -- ~ \~)
+
+                contains -- $plugin $_fisher_plugins || set --universal --append _fisher_plugins $plugin
+                contains -- $plugin $install_plugins && set --local event install || set --local event update
+
+                printf "%s\n" Installing\ (set_color --bold)$plugin(set_color normal) "           "$$plugin_files_var | string replace -- \~ ~
+
+                for file in (string match --regex -- '.+/[^/]+\.fish$' $$plugin_files_var | string replace -- \~ ~)
+                    source $file
+                    if set --local name (string replace --regex -- '.+conf\.d/([^/]+)\.fish$' '$1' $file)
+                        emit {$name}_$event
+                    end
+                end
+            end
+
+            command rm -rf $source_plugins
+
+            if set --query _fisher_plugins[1]
+                set --local commit_plugins
+
+                for plugin in $file_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $_fisher_plugins) && set --append commit_plugins $plugin
+                end
+
+                for plugin in $_fisher_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $commit_plugins) || set --append commit_plugins $plugin
+                end
+
+                string replace --regex -- $HOME \~ $commit_plugins >$fish_plugins
+            else
+                set --erase _fisher_plugins
+                command rm -f $fish_plugins
+            end
+
+            set --local total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
+
+            test "$total" != "0 0 0" && echo (string join ", " (
+                test $total[1] = 0 || echo "Installed $total[1]") (
+                test $total[2] = 0 || echo "Updated $total[2]") (
+                test $total[3] = 0 || echo "Removed $total[3]")
+            ) plugin/s
+        case \*
+            echo "fisher: Unknown command: \"$cmd\"" >&2 && return 1
+    end
+end
+
+if ! set --query _fisher_upgraded_to_4_4
+    set --universal _fisher_upgraded_to_4_4
+    if functions --query _fisher_list
+        set --query XDG_DATA_HOME[1] || set --local XDG_DATA_HOME ~/.local/share
+        command rm -rf $XDG_DATA_HOME/fisher
+        functions --erase _fisher_{list,plugin_parse}
+        fisher update >/dev/null 2>/dev/null
+    else
+        for var in (set --names | string match --entire --regex '^_fisher_.+_files$')
+            set $var (string replace -- ~ \~ $$var)
+        end
+        functions --erase _fisher_fish_postexec
+    end
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/lzd.fish b/airootfs/etc/skel/.config/fish/functions/lzd.fish
new file mode 100644
index 0000000..9cad411
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/lzd.fish
@@ -0,0 +1,3 @@
+function lzd --wraps=lazydocker --description 'alias lzd=lazydocker'
+    lazydocker $argv
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/nvm.fish b/airootfs/etc/skel/.config/fish/functions/nvm.fish
new file mode 100644
index 0000000..64d94c5
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/nvm.fish
@@ -0,0 +1,237 @@
+function nvm --description "Node version manager"
+    for silent in --silent -s
+        if set --local index (contains --index -- $silent $argv)
+            set --erase argv[$index] && break
+        end
+        set --erase silent
+    end
+
+    set --local cmd $argv[1]
+    set --local ver $argv[2]
+
+    if set --query silent && ! set --query cmd[1]
+        echo "nvm: Version number not specified (see nvm -h for usage)" >&2
+        return 1
+    end
+
+    if ! set --query ver[1] && contains -- "$cmd" install use
+        for file in .nvmrc .node-version
+            set file (_nvm_find_up $PWD $file) && read ver <$file && break
+        end
+
+        if ! set --query ver[1]
+            echo "nvm: Invalid version or missing \".nvmrc\" file" >&2
+            return 1
+        end
+    end
+
+    set --local their_version $ver
+
+    switch "$cmd"
+        case -v --version
+            echo "nvm, version 2.2.18"
+        case "" -h --help
+            echo "Usage: nvm install <version>    Download and activate the specified Node version"
+            echo "       nvm install              Install the version specified in the nearest .nvmrc file"
+            echo "       nvm use <version>        Activate the specified Node version in the current shell"
+            echo "       nvm use                  Activate the version specified in the nearest .nvmrc file"
+            echo "       nvm list                 List installed Node versions"
+            echo "       nvm list-remote          List available Node versions to install"
+            echo "       nvm list-remote <regex>  List Node versions matching a given regex pattern"
+            echo "       nvm current              Print the currently-active Node version"
+            echo "       nvm uninstall <version>  Uninstall the specified Node version"
+            echo "Options:"
+            echo "       -s, --silent             Suppress standard output"
+            echo "       -v, --version            Print the version of nvm"
+            echo "       -h, --help               Print this help message"
+            echo "Variables:"
+            echo "       nvm_arch                 Override architecture, e.g. x64-musl"
+            echo "       nvm_mirror               Use a mirror for downloading Node binaries"
+            echo "       nvm_default_version      Set the default version for new shells"
+            echo "       nvm_default_packages     Install a list of packages every time a Node version is installed"
+            echo "       nvm_data                 Set a custom directory for storing nvm data"
+            echo "Examples:"
+            echo "       nvm install latest       Install the latest version of Node"
+            echo "       nvm use 14.15.1          Use Node version 14.15.1"
+            echo "       nvm use system           Activate the system's Node version"
+
+        case install
+            _nvm_index_update
+
+            string match --entire --regex -- (_nvm_version_match $ver) <$nvm_data/.index | read ver alias
+
+            if ! set --query ver[1]
+                echo "nvm: Invalid version number or alias: \"$their_version\"" >&2
+                return 1
+            end
+
+            if test ! -e $nvm_data/$ver
+                set --local os (command uname -s | string lower)
+                set --local ext tar.gz
+                set --local arch (command uname -m)
+                set --local tarcmd tar
+
+                switch $os
+                    case aix
+                        set arch ppc64
+                    case sunos
+                    case linux
+                    case darwin
+                    case {msys_nt,mingw\*_nt}\*
+                        set os win
+                        set ext zip
+                        set tarcmd bsdtar
+                    case \*
+                        echo "nvm: Unsupported operating system: \"$os\"" >&2
+                        return 1
+                end
+
+                switch $arch
+                    case i\*86
+                        set arch x86
+                    case x86_64
+                        set arch x64
+                    case arm64
+                        string match --regex --quiet "v(?<major>\d+)" $ver
+                        if test "$os" = darwin -a $major -lt 16
+                            set arch x64
+                        end
+                    case armv6 armv6l
+                        set arch armv6l
+                    case armv7 armv7l
+                        set arch armv7l
+                    case armv8 armv8l aarch64
+                        set arch arm64
+                end
+
+                set --query nvm_arch && set arch $nvm_arch
+
+                set --local dir "node-$ver-$os-$arch"
+                set --local url $nvm_mirror/$ver/$dir.$ext
+
+                command mkdir -p $nvm_data/$ver
+
+                if ! set --query silent
+                    echo -e "Installing Node \x1b[1m$ver\x1b[22m $alias"
+                    echo -e "Fetching \x1b[4m$url\x1b[24m\x1b[7m"
+                end
+
+                if ! command curl -q $silent --progress-bar --location $url |
+                        command $tarcmd --extract --gzip --directory $nvm_data/$ver 2>/dev/null
+                    command rm -rf $nvm_data/$ver
+                    echo -e "\033[F\33[2K\x1b[0mnvm: Invalid mirror or host unavailable: \"$url\"" >&2
+                    return 1
+                end
+
+                set --query silent || echo -en "\033[F\33[2K\x1b[0m"
+
+                if test "$os" = win
+                    command mv $nvm_data/$ver/$dir $nvm_data/$ver/bin
+                else
+                    command mv $nvm_data/$ver/$dir/* $nvm_data/$ver
+                    command rm -rf $nvm_data/$ver/$dir
+                end
+            end
+
+            if test $ver != "$nvm_current_version"
+                set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
+                _nvm_version_activate $ver
+
+                set --query nvm_default_packages[1] && npm install --global $silent $nvm_default_packages
+            end
+
+            set --query silent || printf "Now using Node %s (npm %s) %s\n" (_nvm_node_info)
+        case use
+            test $ver = default && set ver $nvm_default_version
+            _nvm_list | string match --entire --regex -- (_nvm_version_match $ver) | read ver __
+
+            if ! set --query ver[1]
+                echo "nvm: Can't use Node \"$their_version\", version must be installed first" >&2
+                return 1
+            end
+
+            if test $ver != "$nvm_current_version"
+                set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
+                test $ver != system && _nvm_version_activate $ver
+            end
+
+            set --query silent || printf "Now using Node %s (npm %s) %s\n" (_nvm_node_info)
+        case uninstall
+            if test -z "$ver"
+                echo "nvm: Not enough arguments for command: \"$cmd\"" >&2
+                return 1
+            end
+
+            test $ver = default && test ! -z "$nvm_default_version" && set ver $nvm_default_version
+
+            _nvm_list | string match --entire --regex -- (_nvm_version_match $ver) | read ver __
+
+            if ! set -q ver[1]
+                echo "nvm: Node version not installed or invalid: \"$their_version\"" >&2
+                return 1
+            end
+
+            set --query silent || printf "Uninstalling Node %s %s\n" $ver (string replace ~ \~ "$nvm_data/$ver/bin/node")
+
+            _nvm_version_deactivate $ver
+
+            command rm -rf $nvm_data/$ver
+        case current
+            _nvm_current
+        case ls list
+            _nvm_list | _nvm_list_format (_nvm_current) $argv[2]
+        case lsr {ls,list}-remote
+            _nvm_index_update || return
+            _nvm_list | command awk '
+                FILENAME == "-" && (is_local[$1] = FNR == NR) { next } {
+                    print $0 (is_local[$1] ? " ✓" : "")
+                }
+            ' - $nvm_data/.index | _nvm_list_format (_nvm_current) $argv[2]
+        case \*
+            echo "nvm: Unknown command or option: \"$cmd\" (see nvm -h for usage)" >&2
+            return 1
+    end
+end
+
+function _nvm_find_up --argument-names path file
+    test -e "$path/$file" && echo $path/$file || begin
+        test ! -z "$path" || return
+        _nvm_find_up (string replace --regex -- '/[^/]*$' "" $path) $file
+    end
+end
+
+function _nvm_version_match --argument-names ver
+    string replace --regex -- '^v?(\d+|\d+\.\d+)$' 'v$1.' $ver |
+        string replace --filter --regex -- '^v?(\d+)' 'v$1' |
+        string escape --style=regex || string lower '\b'$ver'(?:/\w+)?$'
+end
+
+function _nvm_list_format --argument-names current regex
+    command awk -v current="$current" -v regex="$regex" '
+        $0 ~ regex {
+            aliases[versions[i++] = $1] = $2 " " $3
+            pad = (n = length($1)) > pad ? n : pad
+        }
+        END {
+            if (!i) exit 1
+            while (i--)
+                printf((current == versions[i] ? " ▶ " : "   ") "%"pad"s %s\n",
+                    versions[i], aliases[versions[i]])
+        }
+    '
+end
+
+function _nvm_current
+    command --search --quiet node || return
+    set --query nvm_current_version && echo $nvm_current_version || echo system
+end
+
+function _nvm_node_info
+    set --local npm_path (string replace bin/npm-cli.js "" (realpath (command --search npm)))
+    test -f $npm_path/package.json || set --local npm_version_default (command npm --version)
+    command node --eval "
+        console.log(process.version)
+        console.log('$npm_version_default' ? '$npm_version_default': require('$npm_path/package.json').version)
+        console.log(process.execPath)
+    " | string replace -- ~ \~
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/precmd.fish b/airootfs/etc/skel/.config/fish/functions/precmd.fish
new file mode 100644
index 0000000..f5a52c9
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/precmd.fish
@@ -0,0 +1,3 @@
+function precmd --wraps="print -Pn '\\e]133;D;%?\\a\\e]133;A\\a'" --description "alias precmd=print -Pn '\\e]133;D;%?\\a\\e]133;A\\a'"
+    print -Pn '\e]133;D;%?\a\e]133;A\a' $argv
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/preexec.fish b/airootfs/etc/skel/.config/fish/functions/preexec.fish
new file mode 100644
index 0000000..cdb4472
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/preexec.fish
@@ -0,0 +1,3 @@
+function preexec --wraps="print -Pn '\\e]133;B\\a\\e]133;C\\a'" --description "alias preexec=print -Pn '\\e]133;B\\a\\e]133;C\\a'"
+    print -Pn '\e]133;B\a\e]133;C\a' $argv
+end
diff --git a/airootfs/etc/skel/.config/fish/functions/update.fish b/airootfs/etc/skel/.config/fish/functions/update.fish
new file mode 100644
index 0000000..4e0c17c
--- /dev/null
+++ b/airootfs/etc/skel/.config/fish/functions/update.fish
@@ -0,0 +1,41 @@
+function update --description 'Automatically finds binarys and uses update commands'
+	if command -v pacman >/dev/null && command -v yay >/dev/null
+		echo "✅ 'pacman' and 'yay' found. Updating."
+		sudo pacman -Syu --noconfirm
+		yay -Syu --sudoloop --save --answerclean None --answerdiff None --noconfirm
+	else if command -v pacman >/dev/null
+		echo "✅ 'pacman' found. Updating."
+		sudo pacman -Syu --noconfirm
+	end
+
+	if command -v paru >/dev/null
+		echo "✅ 'paru' found. Updating."
+		paru -Syu
+	end
+
+	if command -v apt >/dev/null
+		echo "✅ 'apt' found. Updating."
+		sudo apt update && sudo apt full-upgrade -y
+	end
+
+	if command -v hyprpm >/dev/null
+		echo "✅ 'hyprpm' found. Updating."
+		hyprpm reload
+		sleep 2
+		hyprpm update
+	end
+
+	if command -v flatpak >/dev/null
+		echo "✅ 'flatpak' found. Updating."
+		flatpak update -y
+	end
+
+	if command -v npm >/dev/null
+		echo "✅ 'npm' found. Updating."
+		sudo npm install -g npm-check-updates
+	end
+
+	if command -v omz >/dev/null
+		omz update
+	end
+end