Add end-4 hyprland dependecies post-install

2026-09-15 15:37:30 +10:00
parent 94ce80a365
commit df046dcba2
8 changed files with 277 additions and 2 deletions
@@ -0,0 +1,18 @@
+groups=(illogical-impulse)
+pkgname=illogical-impulse-bibata-modern-classic-bin
+pkgver=2.0.6
+pkgrel=2
+pkgdesc="Material Based Cursor Theme, installed for illogical-impulse dotfiles"
+arch=('any')
+url="https://github.com/ful1e5/Bibata_Cursor"
+license=('GPL-3.0-or-later')
+conflicts=("bibata-cursor-theme" "bibata-cursor-theme-bin")
+options=('!strip')
+_variant=Bibata-Modern-Classic
+source=("${pkgname%-bin}-$pkgver.tar.xz::$url/releases/download/v$pkgver/$_variant.tar.xz")
+sha256sums=('SKIP')
+
+package() {
+  install -dm755 "$pkgdir/usr/share/icons"
+  cp -dr --no-preserve=mode $_variant "$pkgdir/usr/share/icons"
+}
@@ -0,0 +1,39 @@
+groups=(illogical-impulse)
+pkgname=illogical-impulse-microtex-git
+_pkgname=MicroTeX
+pkgver=r494.0e3707f
+pkgrel=4
+pkgdesc='MicroTeX for illogical-impulse dotfiles.'
+#pkgdesc="A dynamic, cross-platform, and embeddable LaTeX rendering library"
+arch=("x86_64")
+#url="https://github.com/NanoMichael/${_pkgname}"
+url="https://github.com/end-4/${_pkgname}"
+license=('MIT')
+depends=(
+  tinyxml2
+  gtkmm3
+  gtksourceviewmm
+  cairomm
+)
+makedepends=("git" "cmake")
+source=("git+${url}.git")
+sha256sums=("SKIP")
+
+prepare() {
+  cd $_pkgname
+  sed -i 's/gtksourceviewmm-3.0/gtksourceviewmm-4.0/' CMakeLists.txt
+  sed -i 's/tinyxml2.so.10/tinyxml2.so.11/' CMakeLists.txt
+}
+
+build() {
+  cd $_pkgname
+  cmake -B build -S . -DCMAKE_BUILD_TYPE=None
+  cmake --build build
+}
+
+package() {
+  cd $_pkgname
+  install -Dm0755 -t "$pkgdir/opt/$_pkgname/" build/LaTeX
+  cp -r build/res "$pkgdir/opt/$_pkgname/"
+  install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}
@@ -0,0 +1,82 @@
+_commit='7511545ee20664e3b8b8d3322c0ffe7567c56f7a'
+# Useful links:
+# https://git.outfoxxed.me/quickshell/quickshell/commits/branch/master
+# https://aur.archlinux.org/packages/quickshell-git
+
+groups=(illogical-impulse)
+_prefix='illogical-impulse'
+_pkgname=quickshell
+pkgname="$_prefix-$_pkgname-git"
+pkgver=0.1.0.r1
+pkgrel=8
+pkgdesc="$_pkgname-git pinned commit and extra deps for $_prefix"
+arch=(x86_64 aarch64)
+url='https://git.outfoxxed.me/quickshell/quickshell'
+options=(!strip)
+license=('LGPL-3.0-only')
+depends=(
+  'cpptrace'
+  'jemalloc'
+  'mesa'
+  'qt6-declarative'
+  'qt6-base'
+  'qt6-svg'
+  'libdrm'
+  'libpipewire'
+  'libxcb'
+  'wayland'
+  # NOTE: Below are custom dependencies of illogical-impulse
+  qt6-5compat 
+  qt6-avif-image-plugin
+  qt6-imageformats
+  qt6-multimedia
+  qt6-positioning
+  qt6-quicktimeline
+  qt6-sensors
+  qt6-svg
+  qt6-tools
+  qt6-translations
+  qt6-virtualkeyboard
+  qt6-wayland
+  kirigami
+  kdialog
+  syntax-highlighting
+)
+makedepends=(
+  'cli11'
+  'cmake'
+  'git'
+  'ninja'
+  'qt6-shadertools'
+  'spirv-tools'
+  'vulkan-headers'
+  'wayland'
+  'wayland-protocols'
+)
+provides=("$_pkgname" "$_pkgname-git")
+conflicts=("$_pkgname" "$_pkgname-git")
+
+_pkgsrc="$_pkgname"
+source=("$_pkgsrc::git+$url.git#commit=$_commit"
+  quickshell-check.hook)
+sha256sums=('SKIP'
+  '8543e21aeaaa5441b73a679160e7601a957f16c433e8d6bd9257e80bd0e94083')
+
+build() {
+  cd "$_pkgname"
+  cmake -GNinja -B build \
+    -DCMAKE_BUILD_TYPE="RelWithDebInfo" \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DDISTRIBUTOR="AUR (package: quickshell-git)" \
+    -DDISTRIBUTOR_DEBUGINFO_AVAILABLE=NO \
+    -DINSTALL_QML_PREFIX=lib/qt6/qml
+
+  cmake --build build
+}
+
+package() {
+  install -Dm644 "quickshell-check.hook" -t "$pkgdir/usr/share/libalpm/hooks"
+  cd "$_pkgname"
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/$_pkgname"
+}
@@ -0,0 +1,10 @@
+[Trigger]
+Operation = Upgrade
+Operation = Install
+Type = Package
+Target = qt6-base
+Target = qt6-wayland
+[Action]
+Description = Querying Quickshell compatibility after Qt6 update...
+When = PostTransaction
+Exec = /usr/bin/quickshell --private-check-compat