initial commit

2026-09-25 10:48:51 +10:00
commit b90beea8ae
1020 changed files with 131665 additions and 0 deletions
@@ -0,0 +1,215 @@
+// Test code for Ultimate GPS Using Hardware Serial (e.g. GPS Flora or
+// FeatherWing)
+//
+// This code is similar to GPS_HardwareSerial_Parsing, except for the additional
+// elements to keep track of how long it has been since time and fix data have
+// been received. This approach lets you keep an up to date clock based on GPS
+// time at any time in between GPS fixes.
+//
+// It also shows how to take advantage of the build() function to generate test
+// sentences. The additional code is within #ifdef NMEA_EXTENSIONS and #endif
+// tags.
+//
+// This code shows how to listen to the GPS module via polling. Best used with
+// Feathers or Flora where you have hardware Serial and no interrupt
+//
+// Tested and works great with the Adafruit GPS FeatherWing
+// ------> https://www.adafruit.com/products/3133
+// or Flora GPS
+// ------> https://www.adafruit.com/products/1059
+// but also works with the shield, breakout
+// ------> https://www.adafruit.com/products/1272
+// ------> https://www.adafruit.com/products/746
+//
+// Pick one up today at the Adafruit electronics shop
+// and help support open source hardware & software! -ada
+
+#include <Adafruit_GPS.h>
+
+// what's the name of the hardware serial port?
+#define GPSSerial Serial1
+
+// Connect to the GPS on the hardware port
+Adafruit_GPS GPS(&GPSSerial);
+
+#ifdef NMEA_EXTENSIONS
+// Create another GPS object to hold the state of the boat, with no
+// communications, so you don't need to call Boat.begin() in setup. 
+// We will build some fake sentences from the Boat data to feed to 
+// GPS for testing.
+Adafruit_GPS Boat;
+#endif
+
+// Set GPSECHO to 'false' to turn off echoing the GPS data to the Serial console
+// Set to 'true' if you want to debug and listen to the raw GPS sentences
+#define GPSECHO true
+
+uint32_t timer = millis();
+
+void setup() {
+  // while (!Serial);  // uncomment to have the sketch wait until Serial is
+  // ready
+
+  // connect at 115200 so we can read the GPS fast enough and echo without
+  // dropping chars also spit it out
+  Serial.begin(115200);
+  Serial.println("Adafruit GPS library basic test!");
+
+  // 9600 NMEA is the default baud rate for Adafruit MTK GPS's- some use 4800
+  GPS.begin(9600);
+  // uncomment this line to turn on RMC (recommended minimum) and GGA (fix data)
+  // including altitude
+  GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCGGA);
+  // uncomment this line to turn on only the "minimum recommended" data
+  // GPS.sendCommand(PMTK_SET_NMEA_OUTPUT_RMCONLY);
+  // For parsing data, we don't suggest using anything but either RMC only or
+  // RMC+GGA since the parser doesn't care about other sentences at this time
+  // Set the update rate (uncomment the one you want.)
+  // GPS.sendCommand(PMTK_SET_NMEA_UPDATE_1HZ); // 1 Hz update rate
+  // GPS.sendCommand(PMTK_SET_NMEA_UPDATE_200_MILLIHERTZ); // 5 second update
+  // time
+  GPS.sendCommand(PMTK_SET_NMEA_UPDATE_100_MILLIHERTZ); // 10 second update time
+  // For the parsing code to work nicely and have time to sort thru the data,
+  // and print it out we don't suggest using anything higher than 1 Hz
+
+  // Request updates on antenna status, comment out to keep quiet
+  GPS.sendCommand(PGCMD_ANTENNA);
+
+  delay(1000);
+
+  // Ask for firmware version
+  GPSSerial.println(PMTK_Q_RELEASE);
+}
+
+void loop() // run over and over again
+{
+  // read data from the GPS in the 'main loop'
+  char c = GPS.read();
+  // if you want to debug, this is a good time to do it!
+  if (GPSECHO)
+    if (c)
+      Serial.print(c);
+  // if a sentence is received, we can check the checksum, parse it...
+  if (GPS.newNMEAreceived()) {
+    // a tricky thing here is if we print the NMEA sentence, or data
+    // we end up not listening and catching other sentences!
+    // so be very wary if using OUTPUT_ALLDATA and trytng to print out data
+    // Serial.println(GPS.lastNMEA()); // this also sets the newNMEAreceived()
+    // flag to false
+    if (!GPS.parse(GPS.lastNMEA())) // this also sets the newNMEAreceived() flag
+                                    // to false
+      return; // we can fail to parse a sentence in which case we should just
+              // wait for another
+  }
+
+  // approximately every 2 seconds or so, random intervals, print out the
+  // current stats
+  static unsigned nextInterval = 2000;
+  if (millis() - timer > nextInterval) {
+    timer = millis(); // reset the timer
+    nextInterval = 1500 + random(1000);
+    // Time in seconds keeps increasing after we get the NMEA sentence.
+    // This estimate will lag real time due to transmission and parsing delays,
+    // but the lag should be small and should also be consistent.
+    float s = GPS.seconds + GPS.milliseconds / 1000. + GPS.secondsSinceTime();
+    int m = GPS.minute;
+    int h = GPS.hour;
+    int d = GPS.day;
+    // Adjust time and day forward to account for elapsed time.
+    // This will break at month boundaries!!! Humans will have to cope with
+    // April 31,32 etc.
+    while (s > 60) {
+      s -= 60;
+      m++;
+    }
+    while (m > 60) {
+      m -= 60;
+      h++;
+    }
+    while (h > 24) {
+      h -= 24;
+      d++;
+    }
+    // ISO Standard Date Format, with leading zeros https://xkcd.com/1179/
+    Serial.print("\nDate: ");
+    Serial.print(GPS.year + 2000, DEC);
+    Serial.print("-");
+    if (GPS.month < 10)
+      Serial.print("0");
+    Serial.print(GPS.month, DEC);
+    Serial.print("-");
+    if (d < 10)
+      Serial.print("0");
+    Serial.print(d, DEC);
+    Serial.print("   Time: ");
+    if (h < 10)
+      Serial.print("0");
+    Serial.print(h, DEC);
+    Serial.print(':');
+    if (m < 10)
+      Serial.print("0");
+    Serial.print(m, DEC);
+    Serial.print(':');
+    if (s < 10)
+      Serial.print("0");
+    Serial.println(s, 3);
+    Serial.print("Fix: ");
+    Serial.print((int)GPS.fix);
+    Serial.print(" quality: ");
+    Serial.println((int)GPS.fixquality);
+    Serial.print("Time [s] since last fix: ");
+    Serial.println(GPS.secondsSinceFix(), 3);
+    Serial.print("    since last GPS time: ");
+    Serial.println(GPS.secondsSinceTime(), 3);
+    Serial.print("    since last GPS date: ");
+    Serial.println(GPS.secondsSinceDate(), 3);
+    if (GPS.fix) {
+      Serial.print("Location: ");
+      Serial.print(GPS.latitude, 4);
+      Serial.print(GPS.lat);
+      Serial.print(", ");
+      Serial.print(GPS.longitude, 4);
+      Serial.println(GPS.lon);
+      Serial.print("Speed (knots): ");
+      Serial.println(GPS.speed);
+      Serial.print("Angle: ");
+      Serial.println(GPS.angle);
+      Serial.print("Altitude: ");
+      Serial.println(GPS.altitude);
+      Serial.print("Satellites: ");
+      Serial.println((int)GPS.satellites);
+    }
+#ifdef NMEA_EXTENSIONS
+    char latestBoat[200] = "";
+    updateBoat();                              // create some test data in Boat
+    Boat.build(latestBoat, "GN", "RMC");       // make a sentence from Boat data
+    Serial.print("\nbuild() test output -->"); //
+    Serial.print(latestBoat);                  //
+    GPS.resetSentTime();   // make timing look like it came in on GPS
+    GPS.parse(latestBoat); // parse the test data and store in GPS
+#endif
+  }
+}
+
+#ifdef NMEA_EXTENSIONS
+void updateBoat() { // fill up the boat values with some test data to use in
+                    // build()
+  double t = millis() / 1000.;
+  double theta = t / 100.;   // slow
+  double gamma = theta * 10; // faster
+  Boat.latitude = 4400 + sin(theta) * 60;
+  Boat.lat = 'N';
+  Boat.longitude = 7600 + cos(theta) * 60;
+  Boat.lon = 'W';
+  Boat.fixquality = 2;
+  Boat.speed = 3 + sin(gamma);
+  Boat.hour = abs(cos(theta)) * 24;
+  Boat.minute = 30 + sin(theta / 2) * 30;
+  Boat.seconds = 30 + sin(gamma) * 30;
+  Boat.milliseconds = 500 + sin(gamma) * 500;
+  Boat.year = 1 + abs(sin(theta)) * 25;
+  Boat.month = 1 + abs(sin(gamma)) * 11;
+  Boat.day = 1 + abs(sin(gamma)) * 26;
+  Boat.satellites = abs(cos(gamma)) * 10;
+}
+#endif